###############################################################################
# Guatemala Map - Ian Macky, September 2010
###############################################################################

encoding latin1
device gif 750 800 gt/gt
projection lcc
standard 14 30, 17 20

# leave space at bottom for 36-point label + 6 pixel border top and bottom
window viewport <0, 1, 0.06, 1>
add label <<0.5, .03>>, GUATEMALA, anchor centered, color white, \
    font sans36b, spacing 1.3, flags no-clip

graticule 1
add graticule-labels flags top left inside, tic-length 0, \
    label [font helv12b, color black, border white]

# --- guatemala ---

@(samer3, W100N40) data {}
select guatemala
add 300 guatemala, fill country0, shading 32 .3 hill W100N40 315, 45, 0.01

# --- national capital ---

@data cities
@data instance cc_cities cities
@data filter cc_cities (country = "gt")
@data sort cc_cities population

point guatemala cc_cities guatemala
add point guatemala, capital, \
    label Guatemala, anchor center left, offset 0.9 0, \
	font helv18b, color black

# --- other cities ---

add point cc_cities mixco, city4, \
    label Mixco, anchor center right, \
	offset -0.7, 0, font helv12b, color black

add point cc_cities "villa nueva", city4, \
    label Villa Nueva, anchor center right, \
	offset -0.7, 0, font helv12b, color black

add point cc_cities "san juan sacatepequez", city3, \
    label San Juan//Sacatepequez, anchor bottom right, align center, \
	offset 3.3, 0.5, font helv12b, color black, leading -0.1

add point cc_cities quetzaltenango, city3, \
    label Quetzaltenango, anchor top right, \
	offset 0.5, -0.3, font helv12b, color black

add point cc_cities escuintla, city3, \
    label Escuintla, anchor top left, \
	offset 0.5, -0.2, font helv12b, color black

add point cc_cities chichicastenango, city3, \
    label Chichicastenango, anchor bottom left, \
	offset -1, 0.5, font helv12b, color black, border shaded

add point cc_cities huehuetenango, city3, \
    label Huehuetenango, anchor bottom left, \
	offset 0.5, 0.3, font helv12b, color black, border shaded

add point cc_cities mazatenango, city3, \
    label Mazatenango, anchor bottom right, \
	offset -0.4, 0.3, font helv12b, color black

add point cc_cities "santa lucia cotzumalguapa", \
    circle 3 [color white, fill black], \
    label Santa Lucia//Cotzumalguapa, anchor top right, align center, \
	offset 0.6, 0.2, font helv12b, color black, border shaded, leading -0.1

add point cc_cities "puerto barrios", city3, \
    label Puerto//Barrios, anchor top center, align center, \
	offset 0, -0.4, font helv12b, color black, border shaded, leading -0.1

add point cc_cities "san jose", city3, \
    label San José, anchor bottom center, align center, \
	offset 0, 0.5, font helv12b, color black

add point cc_cities "san francisco el alto", \
    circle 3 [color white, fill black], \
    label San Francisco//el Alto, anchor bottom center, align center, \
	offset 0, 0.5, font helv12b, color black, border shaded, leading -0.1

add point cc_cities coban, city3, \
    label Cobán, anchor bottom center, \
	offset 0, 0.5, font helv12b, color black

point flores cc_cities flores
add point flores, city3, \
    label Flores, anchor top left, \
	offset 0.5, -0.2, font helv12b, color black

# --- other countries ---

color mexico country4
add 300 mexico, fill mexico
add label 16 31, -91 40, MEXICO, anchor centered, font helv24b, \
    color black, border mexico, spacing 0.8

color belize country1
add 300 belize, fill belize
add label 17 0, -88 43, BELIZE, anchor centered, font helv24b, \
    color black, border belize, spacing 0.3

color honduras country2
add 300 honduras, fill honduras
add label 14 50, -88 34, HONDURAS, anchor centered, font helv24b, \
    color black, border honduras, spacing 0.1

color el_salvador country5
add 300 el_salvador, fill el_salvador
add label 13 48, -89 16, EL SALVADOR, anchor centered, \
    font helv24b, color black, border el_salvador

# --- roads ---

data amroad
data filter amroad (category <= 2)
add 350 amroad, color orange

# --- land features ---

add point 15 2 37, -91 54 12, volcano, \
    label Volcán//Tajumulco//4220m, anchor bottom center, \
	align center, offset 0, 2.2, font helv10b, color black, \
	border shaded, leading -0.1

# --- water features ---

040620:040646 add seg sacil3 {}, fill lake-water
add seg sacil3 42211, fill lake-water

add label 15 39, -89 1, Lago de//Izabal, anchor bottom right, align center, \
    font helv12b, color blue

add label 13 56, -91 56, North//Pacific//Ocean, anchor centered, \
    align center, font gent18i, color water-label, border black, \
	leading -0.3

add label 16 7, -88 20, Gulf of//Honduras, anchor centered, \
    align center, font gent16i, color water-label, border black, \
	leading -0.3

# --- rivers ---

data instance samer-rivers sariv3
data filter samer-rivers ((type = 60) || (type = 62))
add samer-rivers

add label 15 0 30, -89 30, Grande, anchor centered, \
    font helv12i, rot 23, cmap river-shaded

# --- scale bar ---

add scale-bar <.22, .035>, .25, between guatemala flores, \
    color white, border black, font clea12, units both

# --- overview window ---

window new gt-ov <<0.017, 0.222, 0.800 0.986>>, border 2
projection orthographic
select guatemala, zoom .1
graticule 30
add background lmask10

@data mwdb3
add 300 mwdb3 guatemala, color red, fill red
add 300 country3

# $Id: gt.cmd,v 1.22 2011/05/13 03:33:35 ian Exp $